first commit

examples/rf22/rf22_mesh_server2/rf22_mesh_server2.ino

@@ -0,0 +1,56 @@
+// rf22_mesh_server1.pde
+// -*- mode: C++ -*-
+// Example sketch showing how to create a simple addressed, routed reliable messaging server
+// with the RHMesh class.
+// It is designed to work with the other examples rf22_mesh_*
+// Hint: you can simulate other network topologies by setting the 
+// RH_TEST_NETWORK define in RHRouter.h
+
+// Mesh has much greater memory requirements, and you may need to limit the
+// max message length to prevent wierd crashes
+#define RH_MESH_MAX_MESSAGE_LEN 50
+
+#include <RHMesh.h>
+#include <RH_RF22.h>
+#include <SPI.h>
+
+// In this small artifical network of 4 nodes,
+#define CLIENT_ADDRESS 1
+#define SERVER1_ADDRESS 2
+#define SERVER2_ADDRESS 3
+#define SERVER3_ADDRESS 4
+
+// Singleton instance of the radio driver
+RH_RF22 driver;
+
+// Class to manage message delivery and receipt, using the driver declared above
+RHMesh manager(driver, SERVER2_ADDRESS);
+
+void setup() 
+{
+  Serial.begin(9600);
+  if (!manager.init())
+    Serial.println("RF22 init failed");
+  // Defaults after init are 434.0MHz, 0.05MHz AFC pull-in, modulation FSK_Rb2_4Fd36
+}
+
+uint8_t data[] = "And hello back to you from server2";
+// Dont put this on the stack:
+uint8_t buf[RH_MESH_MAX_MESSAGE_LEN];
+void loop()
+{
+  uint8_t len = sizeof(buf);
+  uint8_t from;
+  if (manager.recvfromAck(buf, &len, &from))
+  {
+    Serial.print("got request from : 0x");
+    Serial.print(from, HEX);
+    Serial.print(": ");
+    Serial.println((char*)buf);
+
+    // Send a reply back to the originator client
+    if (manager.sendtoWait(data, sizeof(data), from) != RH_ROUTER_ERROR_NONE)
+      Serial.println("sendtoWait failed");
+  }
+}
+